10 Integrales de funciones de varias variables

10.1 Ejercicios Resueltos

Para la realización de esta práctica se requieren los siguientes paquetes:

using SymPy  # Para el cálculo simbólico.
using HCubature # Para el cálculo numérico de integrales múltiples.

Ejercicio 10.1 Calcular el volumen de las siguientes figuras geométricas usando integrales múltiples.

Ayuda

Para calcular numéricamente integrales definidas de funciones de varias variables usar la función hcubature del paquete HCubature.

Este paquete toma como argumento una función vectorizada. Para crear una función vectorizada a partir de una función escalar se puede usar f(v) = f(v...).

Un paralelogramo de base rectangular \([0,1]\times [0,5]\) y altura \(10\).

Solución

using HCubature
f(x, y) = 10
f(v) = f(v...)
hcubature(f, [0,0], [1,5])

(50.0, 7.105427357601002e-15)

Una cuña de base rectangular \([0,2]\times [0,5]\) y altura \(10\).

Solución

f(x, y) = 10x
f(v) = f(v...)
hcubature(f, [0,0], [1,5])

(25.0, 3.552713678800501e-15)

Un cilindro de base circular centrada en el origen con radio \(1\) y altura \(10\).

Solución

f(x, y) = x^2+y^2<1 ? 10 : 0
f(v) = f(v...)
hcubature(f, [-1,-1], [1,1])

(31.41598951201623, 4.6813472010342655e-7)

Una semiesfera centrada en el origen con radio \(1\).

Solución

f(x, y) = x^2+y^2<1 ? sqrt(1-x^2-y^2) : 0
f(v) = f(v...)
hcubature(f, [-1,-1], [1,1])

(2.0943951101375893, 3.12087277156216e-8)

Ejercicio 10.2 Calcular las siguientes integrales iteradas.

Ayuda

Para calcular la primitiva de una función se puede usar la función integrate del paquete SymPy.

\(\int_0^1\int_0^2 x+y \,dy\,dx\).

Solución

using SymPy
@syms x y
f(x, y) = x + y
integrate(f(x,y), (y, 0, 2), (x, 0, 1))

\(3\)

\(\int_0^2\int_0^1 x+y \,dx\,dy\).
Solución
integrate(f(x,y), (x, 0, 1), (y, 0, 2))

\(3\)

\(\int_0^1\int_0^2\int_0^3 xyz \,dz\,dy\,dx\).

Solución

@syms z
f(x, y, z) = x * y * z
integrate(f(x,y,z), (z, 0, 3), (y, 0, 2), (x, 0, 1))

\(\frac{9}{2}\)

\(\int_0^3\int_0^1\int_0^2 xyz \,dy\,dx\,dz\).

Solución

@syms z
f(x, y, z) = x * y * z
integrate(f(x,y,z), (y, 0, 2), (x, 0, 1), (z, 0, 3))

\(\frac{9}{2}\)

Ejercicio 10.3 Calcular las siguientes integrales dobles sobre las regiones dadas.

\(\int_0^2\int_0^{x/2} e^{x+y}\,dy\,dx\).
Solución
using SymPy @syms x y f(x, y) = exp(x+y) integrate(f(x,y), (y, 0, x/2), (x, 0, 2))

\(- e^{2} + \frac{1}{3} + \frac{2 e^{3}}{3}\)
Calcular la integral anterior invirtiendo el orden de integración.
Solución
integrate(f(x,y), (x, 2y, 2), (y, 0, 1))

\(- e^{2} + \frac{1}{3} + \frac{2 e^{3}}{3}\)
\(\int_0^1\int_x^{\sqrt{x}} x^2y\,dy\,dx\).
Solución
f(x, y) = x^2*y integrate(f(x,y), (y, x, sqrt(x)), (x, 0, 1))

\(\frac{1}{40}\)
Calcular la integral anterior invirtiendo el orden de integración.
Solución
integrate(f(x,y), (x, y^2, y), (y, 0, 1))

\(\frac{1}{40}\)
\(\int_0^1\int_y^1 \cos(x^2) \,dx\,dy\).
Solución
f(x, y) = cos(x^2) integrate(f(x,y), (x, y, 1), (y, 0, 1))

\(- \frac{\sqrt{2} \sqrt{\pi} \left(- \frac{\sqrt{2} \sin{\left(1 \right)} \Gamma\left(\frac{1}{4}\right)}{8 \sqrt{\pi} \Gamma\left(\frac{5}{4}\right)} + \frac{C\left(\frac{\sqrt{2}}{\sqrt{\pi}}\right) \Gamma\left(\frac{1}{4}\right)}{4 \Gamma\left(\frac{5}{4}\right)}\right) \Gamma\left(\frac{1}{4}\right)}{8 \Gamma\left(\frac{5}{4}\right)} + \frac{\sqrt{2} \sqrt{\pi} C\left(\frac{\sqrt{2}}{\sqrt{\pi}}\right) \Gamma\left(\frac{1}{4}\right)}{8 \Gamma\left(\frac{5}{4}\right)}\)
Como la función \(\cos(x^2)\) no tiene primitiva inmediata, el resultado aparece en función de a función de la integral de Fresnel. Sin embargo, resulta más sencillo calcular esta integral doble iterada invirtiendo el orden de integración, es decir, \(\int_0^1\int_0^x \cos(x^2) \,dy\,dx\).
integrate(f(x,y), (y, 0, x), (x, 0, 1))

\(\frac{\sin{\left(1 \right)}}{2}\)

Ejercicio 10.4 Calcular los volúmenes que quedan por debajo de las funciones siguientes en las regiones dadas.

\(x + 2y + 3z = 6\) en el primer octante.

Solución

using SymPy
@syms x y z
# Despejamos z y la expresamos en función de x e y.
f(x, y) = solve(x+2y+3z-6, z)[1]
# Obtenemos los límites de integración en y.
g(x) = solve(f(x,y), y)[1]
# Obtenemos los límites de integración en x.
b = solve(g(x))[1]
# Calculamos la integral doble.
integrate(f(x,y), (y, 0, g(x)), (x, 0, b))

\(6\)

\(f(x,y) = xy\) en \([-1,1]\times [-1,1]\).
Solución
En este caso la integral doble no nos da el volumne, porque hay subintervalos donde la función es negativa. Para ello debemos descomponer la región en subregiones donde la función siempre tenga el mismo signo y sumar los volúmenes de cada una de ellas.
f(x, y) = x*y integrate(f(x,y), (y, -1, 0), (x, -1, 0)) + integrate(-f(x,y), (y, -1, 0), (x, 0, 1)) + integrate(-f(x,y), (y, 0, 1), (x, -1, 0)) + integrate(f(x,y), (y, 0, 1), (x, 0, 1))

\(1\)
En este caso resulta más sencillo utilizar la función hcubature del paquete HCubature.
using HCubature f(x, y) = abs(x*y) f(v) = f(v...) hcubature(f, [-1,-1], [1,1])

(1.0, 0.0)

Ejercicio 10.5 Un balsa de residuos líquidos con forma elíptica de ecuación \(2x^2 + y^2 = 9\) tiene una profundidad dada por la función \(f(x,y) = \frac{x^2}{2} + \frac{y^2}{2} - 10\). Calcular el volumen de la balsa.

Solución

using SymPy
@syms x y
# Función de la superficie
f(x, y) = x^2/2 + y^2/2 - 10 
# Función de la región de integración
g(x, y) = 2x^2 + y^2 - 9
# Límites de integración en y
soly = solve(g(x, y), y)
# Límites de integración en x
solx = solve(g(x, 0))
integrate(f(x, y), (y, soly[1], soly[2]), (x, solx[1], solx[2]))

\(- \frac{1197 \sqrt{2} \pi}{32}\)

Ejercicio 10.6 Calcular el volumen comprendido entre las superficies de las funciones \(f(x,y)=x^2+y^2\) y \(g(x,y)=2x\).

Solución

using SymPy
@syms x y
f(x, y) = x^2 + y^2
g(x, y) = 2x
# Límites de integración en y
soly = solve(f(x,y)-g(x,y), y)
# Límites de integración en x
solx = solve(soly[1])
# Calculamos el volumen
integrate(g(x,y)-f(x,y), (y, soly[2], soly[1]), (x, solx[1], solx[2]))

\(\frac{\pi}{2}\)

Ejercicio 10.7 Una tolva tiene forma cónica dada por la función \(f(x,y)=2\sqrt{x^2+y^2}\) con altura 4 m. Calcular el volumen de la tolva y la cantidad de chapa necesaria para construirla.

Ayuda

El área de la superficie de una función \(f(x,y)\) sobre una región \(R\) puede calcularse mediante la integral

\[ A_{R}(f) = \int_R \sqrt{f'_x(x_i,y_j)^2 + f'_y(x_i,y_j)^2 + 1}\,dA. \]

Solución

Para calcular el volumen es más sencillo trabajar en coordenadas polares.

using SymPy
@syms x y r θ
f(x, y) = 2*sqrt(x^2+y^2)
# Función en coordenadas polares
g(r, θ) = f(r*cos(θ), r*sin(θ))
# Límites de integración en r
solr = solve(g(r,θ)-4, r)
integrate(4 - g(r,θ)*r, (r, 0, solr[2]), (θ, 0, 2PI))

\(\frac{16 \pi}{3}\)

Para calcular en área de la superficie trabajamos en coordenadas rectangulares.

# Límites de integración en y
soly = solve(f(x,y)-4, y)
# Límites de integración en x
solx = solve(f(x,0)-4)
integrate(sqrt(diff(f(x,y), x)^2 + diff(f(x,y), y)^2 +1), (y, soly[1], soly[2]), (x, solx[1], solx[2]))

\(4 \sqrt{5} \pi\)

Ejercicio 10.8 Una placa metálica delimitada por las curvas \(y=2-x^2\) e \(y=-3+2x^2\) tiene una densidad dada por la función \(d(x,y)=x^2y^2\).

Calcular la masa de la placa.

Ayuda

La masa de una región plana con densidad variable \(\delta(x,y)\) se calcula mediante la integral.

\[ \int_R \delta(x,y)\,dA. \]

Solución

using SymPy
@syms x y
d(x,y) = x^2 * y^2
g(x) = 2 - x^2
h(x) = -3 + 2x^2
# Límites de integración en x
sol = solve(g(x)-h(x), x)
m = integrate(d(x,y), (y, h(x), g(x)), (x, sol[1], sol[2]))

\(\frac{460 \sqrt{15}}{729}\)

Calcular el centro de masas de la placa

Ayuda

Las coordenadas del centro de masas se obtienen mediante las siguientes integrales.

\[\begin{align*} \bar x &= \frac{M_y}{m} = \frac{\int_R x\delta(x,y)\,dA}{\int_R \delta(x,y)\,dA} \\ \bar y &= \frac{M_x}{m} = \frac{\int_R y\delta(x,y)\,dA}{\int_R \delta(x,y)\,dA} \end{align*}\]
Solución
Calculamos primero la componente \(x\) del centro de masas.
# Momento con respecto a y my = integrate(x*d(x,y), (y, h(x), g(x)), (x, sol[1], sol[2])) # Centro de masas en x. my / m

\(0\)
Y después la componente \(y\) del centro de masas.
# Momento con respecto a x mx = integrate(y*d(x,y), (y, h(x), g(x)), (x, sol[1], sol[2])) # Centro de masas en y. mx / m

\(- \frac{4159}{5313}\)

10.2 Ejercicios propuestos

Ejercicio 10.9 Calcular la integral \(\int_{-1}^1\int_{-2y}^{2} e^{x^2}\,dx\,dy\)

Ejercicio 10.10 Calcular el volumen de la región encerrada por las superficies \(z^2=4-x\), \(y^2=4-x\) y \(x=0\).

Ejercicio 10.11 Calcular el volumen encerrado por la superficie de la función \(f(x,y)=\ln(\cos(x+y)+2)\) y el plano \(z=0\) en la región delimitada por la circunferencia de radio \(1\) centrada en el origen de coordenadas.

Ejercicio 10.12 Calcular el area de la superficie de la función \(f(x,y)=\sqrt{x+y}\) en el intervalo \([0,1]\times[0,1]\).

Ejercicio 10.13 Calcular el centro de masas de la región plana delimitada por las funciones \(y=\sqrt{x}\) e \(y=x^2\) con densidad \(d(x,y)= \ln(x+2y+1)\).

Coordenada x

Coordenada y